-
Intercaleu al final del llibre
un nou full de càlcul, anomeneu-lo Sorteig i desactiveu la visió
de la quadrícula.
-
Entreu a les cel·les
B2, B3, E2 i G2 els rètols corresponents i ajusteu l'amplada de
les columnes el que convingui per tal que hi càpiguen els rètols.
No oblideu que la columna F encara no ha d'estar amagada.
-
Entreu a la cel·la I1
la fórmula següent, sense oblidar d'escriure el signe = i les
cometes
(= ""):
="010203040506070809101112131415161718192021222324252627282930
313233343536373839404142434445464748495051525354555657585960616263 646566676869707172737475767778798081828384858687888990919293949596979899"
Com podeu observar aquí
teniu escrits els nombres naturals fins al 99, fent servir dues xifres
per cadascun i posats entre cometes per tal que tot sigui considerat com
una paraula o cadena de text.
-
Entreu els nombres de les cel·les
C2 i C3. El nombre de la cel·la C2 indicarà quin és
l'últim nombre que entra en el sorteig i el de la cel·la
C3 fixa quants nombres no repetits cal triar a l'atzar. Evidentment, per
a un correcte funcionament, C3 ha de ser més petit o igual que C2.
-
Entreu a la cel·la I2
la fórmula =IZQUIERDA(I1;C2*2).
Si varieu el contingut
de la cel·la C2 comprovareu que la fórmula anterior "retalla",
de tota la cadena de la cel·la I1, el tros que conté els
nombres desitjats.
Busqueu
informació sobre les funcions IZQUIERDA i DERECHA.
-
Entreu el nombre 1 a la cel·la
E3.
-
Entreu a la cel·la F3
la fórmula =ENTERO(ALEATORIO()* C2)+1.
La fórmula
anterior escriurà un nombre enter escollit a l'atzar situat entre
l'1 i el que indiqui C2.
-
Entreu a la cel·la G3
la fórmula =VALOR(EXTRAE( I2;(F3-1)*2+1;2)).
Aquesta fórmula
extraurà de la cadena I2 les dues xifres situades en el lloc indicat
per la cel·la F3 i les traduirà a valor numèric.
Busqueu
informació sobre les funcions VALOR i EXTRAE.
-
Entreu a la cel·la I3
la fórmula següent:
=IZQUIERDA(I2;(F3-1)*2)&DERECHA(I2;LARGO(I2)-F3*2)
Aquesta fórmula
escriurà la mateixa cadena que hi havia a I2, però sense
que figuri la representació del nombre que ja ha sortit abans. D'aquesta
manera s'evita que hi hagi repeticions.
Busqueu
informació sobre la funció LARGO.
-
Entreu a la cel·la E4
la fórmula:
=SI(FILAS(E$3:E4)<=C$3;E3+1;"")
Aquesta fórmula,
que després copiareu a les cel·les que estan per sota de
l'actual, serveix per continuar comptant noves tries de nombres, tantes
com el contingut de la cel·la C3 ho indiqui.
Busqueu
informació sobre les funcions FILAS i COLUMNAS.
-
Entreu a la cel·la F4
la fórmula:
=SI(E4="";"";ENTERO(ALEATORIO()*(C$2+1-E4))+1)
Amb aquesta fórmula,
si la cel·la E4 no és buida, es farà un nou sorteig,
però tenint en compte que cada vegada hi ha un nombre menys entre
els quals encara no han sortit.
-
Entreu a G4 la fórmula:
=SI(E4="";"";VALOR(EXTRAE(I3;(F4-1)*2+1;2)))
Si E4 no és buida,
extraurà de la cadena I3 el nombre que ocupi el lloc indicat pel
sorteig efectuat a F4 i li donarà un valor numèric. Els nombres
que van sortint en aquesta columna són escollits a l'atzar, però,
gràcies a les altres fórmules de les cel·les veïnes,
s'eviten les possibles repeticions.
-
Entreu a I4 la fórmula:
=SI(E4="";"";IZQUIERDA(I3;(F4-1)*2)&DERECHA(I3;
LARGO(I3)-F4*2))
Té el mateix efecte
que la fórmula de la cel·la I3, sempre que la cel·la
E4 no estigui buida.
-
Seleccioneu el rang E4:I4 i
copieu el seu contingut, arrossegant la selecció, sobre el rang
E5:I101. D'aquesta manera es podrà escollir un màxim de 99
nombres diferents.
-
Entreu 12 i 5 a les cel·les
C2 i C3, respectivament. Cada cop que premeu la tecla F9 es farà
una nova tria a l'atzar de nombres amb les característiques indicades
a les cel·les C2 i C3.
-
Seleccioneu la cel·la
C2 i accediu a Datos | Validación... i feu que només
es puguin entrar nombres enters de l'1 al 99. Cal que surti un missatge
d'error.
-
Seleccioneu la cel·la
C3 i amb Datos | Validación... feu que només es puguin
entrar nombres enters de l'1 al que s'hagi entrat en C2. Per això
cal que en la fitxa Configuración s'hagi entrat Número
entero en Permitir, entre en Datos, 1 en Mínimo
i
=C2 en Máximo. Cal que surti també el corresponent
missatge d'error.
-
Canvieu els valors de C2 i C3
i premeu la tecla F9 més cops. Provoqueu que surti algun missatge
d'error.
-
Amagueu la columna F.
-
Seleccioneu la columna I. Ara
fareu invisible el contingut d'aquesta columna sense esborrar-lo: Activeu
Formato | Celdas... | Fuente | Color: blanc
-
Seleccioneu
el rang B2:C3 i afegiu una quadrícula de color blau. [1
]
-
Feu el mateix en el rang E2:G101.
-
Seleccioneu
el rang B2:B3 i feu que tingui un fons blau amb les lletres blanques. [2]
-
Feu el mateix amb el rang E2:G2.
-
Doneu un fons groc clar als
rangs C2:C3 i E3:G101.
-
Protegiu les cel·les
que creieu convenients.
-
Deseu el llibre.
